모든 Excel 전문가가 이해해야 하는 IF와 SWITCH 함수 비교

들어가기 전에

IF 함수는 Excel에서 인기 있는 논리 함수 중 하나입니다. SWITCH 함수는 IF에 비해서는 덜 알려져 있지만 IF 문 대신 사용할 수 있습니다. IF와 SWITCH 함수의 개념과 사용 사례를 소개합니다.

권현욱(엑셀러) | 아이엑셀러 닷컴 대표 · Microsoft Excel MVP · Excel 솔루션 프로바이더 · 작가

이미지: 아이엑셀러 닷컴

---

이 글은 아래 기사 내용을 토대로 작성되었습니다만, 필자의 개인 의견이나 추가 자료들이 다수 포함되어 있습니다.

• 원문: Every Excel Pro Needs to Understand IF and SWITCH: Here's How They Compare
• URL: https://www.makeuseof.com/excel-if-vs-switch-function/

---

IF 함수

Excel의 IF 문은 지정된 조건이 참인지 거짓인지 판단하기 위해 논리 테스트를 수행하는 함수입니다. 평가 결과에 따라 값을 반환하므로 결과에 따라 의사 결정을 내릴 수 있습니다.

기본 IF 문

기본 IF 문에 대한 문제, 즉 SWITCH가 해결하고자 하는 문제를 이해하기 위해 기본 IF 문부터 살펴봅니다. 기본 IF 문의 구문은 다음과 같습니다.

IF (logical_test, result_if_true, [result_if_false])

 

대괄호 안에 있는 매개변수는 선택 사항이므로 생략할 수 있습니다.

 

logical_test 매개변수는 함수가 검사할 조건이며, result_if_true는 평가 결과가 true인 경우 반환하는 결과입니다. result_if_false 매개변수는 평가 결과가 false인 경우 반환되는 결과입니다.

아래 스크린샷에서는 C 열의 시험 점수 값이 50보다 크거나 같은지 여부에 따라 성적에 대해 합격 또는 불합격을 반환하려고 합니다.

 

이미지: muo

 

다음 수식을 C2 셀에 작성합니다.

=IF(C2 >= 50, "Pass", "Fail")

 

아래 셀에 공식을 복사하면 나머지 사람들의 성적을 구할 수 있습니다.

 

중첩 IF 문

여러 조건을 동시에 테스트하려는 경우 다른 조건 안에 IF 문을 배치할 수 있습니다. 이를 중첩 IF 문이라고 하며 기본 구문은 다음과 같습니다.

=IF(logical_test1, result_if_true1, IF(logical_test2, result_if_true2, result_if_false2))

 

아래 예에서, A 열의 각 색상(빨간색, 노란색 또는 초록색)은 B 열에 해당하는 상태(예: 중지, 주의, 이동 및 알 수 없음)를 표시하고자 합니다.

 

이미지: muo

 

B2 셀에 다음 수식을 입력합니다.

=IF(A2 = "Red", "Stop", IF(A2 = "Yellow", "Caution", IF(A2 = "Green", "Go", "Unknown")))

 

A2는 빨간색이므로 위의 수식에 따라 Stop을 반환합니다. 다른 셀에 복사하면 모든 색상에 대해 상태가 표시됩니다.

 

IF 문을 중첩할수록 로직이 복잡하고 혼란스러워질 수 있습니다. 이런 경우 SWITCH 함수를 사용하면 단순화할 수 있습니다.

SWITCH 함수

Excel의 SWITCH는 비교적 새로운 함수입니다. 중첩된 IF 문에 비해 더 읽기 쉽고 구조화된 형식으로 표현식을 가져와 여러 결과에 대해 테스트합니다. SWITCH 함수의 기본 구문은 다음과 같습니다.

SWITCH (expression_to_test, test_value1, result_if_true1, [test_value2, result_if_true2,…], [value_if_no_match])

 

expression_to_test는 테스트 값(test_value1, test_value2 등)에 대해 평가할 값입니다. 일치하는 값이 있으면 해당 결과를 반환합니다. 예를 들어 test_value1이 표현식과 일치하면 result_if_true1을 반환합니다. 일치하는 항목이 없는 경우 값을 반환하도록 value_if_no_match 매개변수를 지정할 수 있습니다.

SWITCH 문은 중첩된 IF를 단순화할 수 있으므로 중첩된 IF의 색상 예제를 사용할 수 있습니다. 앞에서 사용했던 중첩 IF 문을 SWITCH 함수로는 다음과 같이 나타낼 수 있습니다.

=SWITCH(A2, "Red", "Stop", "Yellow", "Caution", "Green", "Go", "Unknown")

 

수식이 더 읽기 쉬워졌으며 IF 버전과 동일하게 작동함을 알 수 있습니다.

IF와 SWITCH 함수 비교 

SWITCH와 비교할 때, IF 문은 여러 조건이 포함된 복잡한 논리 테스트를 수행할 때 잘 사용됩니다. 또한 테스트에서 Excel의 다양한 논리 연산자(예: >, <, =, <>, AND 및 OR)를 사용할 때도 잘 작동합니다. 따라서 SWITCH 문보다 더 유연하고 동적인 상황을 처리할 수 있습니다.

반면 SWITCH 문은 기본 형식이 같음 연산자만 평가하기 때문에 논리 테스트가 단순한 같음과 고정값을 포함하는 경우에 적합합니다. 복잡한 논리 테스트에 SWITCH 문을 사용하는 것은 IF 문을 사용하는 것과 다르지 않습니다. 복잡한 중첩된 IF 문을 예로 들어 보겠습니다.

=IF(A1 >= 90, "Grade A", IF(A1 >= 75, "Grade B", "Grade C"))

 

아래와 같이 SWITCH 함수를 할 수 있습니다.

=SWITCH(TRUE, A1 >= 90, "Grade A", A1 >= 75, "Grade B", A1 < 75, "Grade C")

 

 

Excel의 다른 함수와 마찬가지로 이러한 함수를 결합할 수 있습니다. SWITCH 문 안에 IF 문을 배치할 수 있고 그 반대의 경우도 마찬가지입니다. 또한 SUM, INDEX, MATCH, XLOOKUP과 같은 다른 함수에 삽입할 수도 있습니다.

 

마치며

분기 처리할 조건이 많을 경우, SWITCH 함수를 사용하면 구조적인 표현이 가능합니다. IFS 함수를 사용할 수도 있습니다. 엑셀의 헷갈리는 조건 분기 처리에 대해서는 [여기]를 참고하세요.

멤버십 안내 "최고" 가성비로 "최신" Office 활용 정보를 보내드립니다.

추천 도서 심혈을 기울여 집필한 책들입니다. 자신있게 추천합니다.

강의 & 개발 최고 전문가의 실무 노하우를 아낌 없이 전수해 드립니다.

---